mirror of
https://github.com/ganelson/inform.git
synced 2024-07-05 16:44:21 +03:00
36 lines
2.2 KiB
Plaintext
36 lines
2.2 KiB
Plaintext
* Defining new prepositions
|
|
(Hiding things under other things; Beneath the Surface)
|
|
An "underlying" relation which adds to the world model the idea of objects hidden under other objects.
|
|
|
|
The standard world model provides for the idea of containers and supporters, but this is not the only way that objects can relate to one another in the real world. Here we try adding the idea of concealment beneath another object:
|
|
|
|
{*}"Beneath the Surface"
|
|
|
|
Section 1 - In Which our Terms are Defined
|
|
|
|
Underlying relates various things to one thing. The verb to underlie means the underlying relation. The verb to be under means the underlying relation. The verb to be beneath means the underlying relation.
|
|
|
|
Instead of looking under a thing which is underlaid by something (called the lost object):
|
|
say "You find [the list of things which underlie the noun]!";
|
|
now every thing which underlies the noun is carried by the player;
|
|
now every thing which underlies the noun does not underlie the noun.
|
|
|
|
Hiding it under is an action applying to one carried thing and one thing. Understand "put [something preferably held] under [something]" as hiding it under. Understand "hide [something preferably held] under [something]" as hiding it under. Understand the commands "shove" and "conceal" and "stick" as "hide".
|
|
|
|
Check hiding it under:
|
|
if the second noun is not fixed in place, say "[The second noun] wouldn't be a very effective place of concealment." instead.
|
|
|
|
Carry out hiding it under:
|
|
now the noun is nowhere;
|
|
now the noun underlies the second noun.
|
|
|
|
Report hiding it under:
|
|
say "You shove [the noun] out of sight beneath [the second noun]."
|
|
|
|
Section 2 - In Which They are Put To Use
|
|
|
|
The Room of Hidden Objects is a room. It contains a sofa, an easy chair, and a rug. The sofa supports a lime-green pillow and an innocent-looking Chinese finger toy. The rug is fixed in place. The chair is a supporter.
|
|
|
|
A treasure map underlies the easy chair. A skeleton is beneath the sofa. A blueprint of Atlantis, a lexicon of Linear A, and the key to Jimmy Hoffa's Mausoleum are under the rug.
|
|
|
|
Test me with "look under the sofa / look under the rug / look under the easy chair / hide lexicon under rug". |