mirror of
https://github.com/ganelson/inform.git
synced 2024-07-16 22:14:23 +03:00
54 lines
2.6 KiB
Plaintext
54 lines
2.6 KiB
Plaintext
*** New actions
|
|
(SHAKE command; 3 AM)
|
|
A shake command which agitates soda and makes items thump around in boxes.
|
|
|
|
{*}"3 AM"
|
|
|
|
Understand "shake [something preferably held]" as shaking.
|
|
|
|
Shaking is an action applying to one carried thing.
|
|
|
|
Carry out shaking:
|
|
say "Nothing results of your shaking [the noun]."
|
|
|
|
Instead of shaking a closed container when something is in the noun:
|
|
say "Something rattles inside [the noun]."
|
|
|
|
Instead of shaking a closed transparent container when something is in the noun:
|
|
say "Inside [the noun] there are banging noises produced by [the list of things contained by the noun]."
|
|
|
|
Instead of shaking an open container which contains something:
|
|
say "[The list of things contained by the noun] might fly out."
|
|
|
|
The Wawa is a room. "A convenience store, if you like to call it that, vending the usual assortment of chips, donuts, soda, and beer. There is something of a line at the sandwich counter."
|
|
|
|
The box of enrobed cakes is in the Wawa. "A box of Tastykake Enrobed Cakes has fallen off its shelf." The description is "'Enrobed Cakes' is a fancy term for 'strange sponge-like baked good, covered in a thin shell of waxy chocolate'. They are addictive, but not in a way that lets you respect yourself in the morning." The box is a closed openable container. In the box is a cake.
|
|
|
|
Instead of opening the box, say "The Wawa clerks frown on the consumption of unpurchased foodstuffs."
|
|
|
|
The can of root beer is a closed openable container carried by the player. The can of root beer is either agitated or calm.
|
|
|
|
Because the can of root beer should have some reactions to having been shaken later in the game, we need to borrow a few ideas from the chapter on Time:
|
|
|
|
{**}Instead of shaking the can of root beer:
|
|
the can calms down in five turns from now;
|
|
say "You give the can a good hard shake.";
|
|
now the can is agitated.
|
|
|
|
Instead of listening to the can: say "It sounds [if agitated]fizzy[otherwise]calm[end if]!"
|
|
|
|
At the time when the can calms down:
|
|
now the can is calm.
|
|
|
|
The sticky mess is fixed in place. "There is a sticky mess on the ground."
|
|
|
|
Instead of opening the agitated can of root beer:
|
|
now the can of root beer is nowhere;
|
|
now the sticky mess is in the location;
|
|
say "You open the can and fizzing sweet soda goes absolutely everywhere."
|
|
|
|
Instead of opening the calm can of root beer when the can has been agitated:
|
|
now the can of root beer is nowhere;
|
|
say "The root beer is disappointingly flat. That's what you get for shaking it up!"
|
|
|
|
Test me with "get box / shake box / open box / shake box / listen to can / shake can / listen to can / wait / wait / wait / wait / wait / listen to can / open can". |